@echo off
rem
rem
rem Pruefen/Konvertieren und Senden von VDN-Netz- und Störungsdaten (XML Format)
rem mit dem VDN Prüfprogramm
rem
rem Parameter: 
rem P1: Aufgabe des Prüfprogrammes 
rem     pruefen : Prüfen der VDN-Netz-/Störungsdaten
rem     konvert : Konvertieren der VDN-Netz-/Störungsdaten ins BNetzA-Format
rem     senden  : Konvertieren der VDN-Netz-/Störungsdaten ins BNetzA-Format und Senden 
rem P2: Installationsverzeichnis für VDN Pruefprogramm
rem P3: Installationsverzeichnis für Java-Laufzeitsystem
rem P4: Bin-Verzeichnis des Java-Laufzeitsystem
rem P5: Name der zu prüfenden Datei/Verzeichnis
rem P6: Name der Protokolldatei (XML)
rem P7: Name des BNA-Ausgabeordners (nur bei konvert und senden)
rem P8: Proxy-Username (nur bei senden)
rem P9: Proxy-Passwort (nur bei senden)
rem
rem
rem ACHTUNG Parameter NICHT mit " einschliessen da beim Aufruf über Interass diese bereits gesetzt sind !!!
rem
rem Pietsch 02.03.05
rem Brozio  12.02.07
rem Brozio  01.06.07 Version 3_0_1 und Vergrößerung des Hauptspeicher des Prüfprogammes
rem Pietsch 15.06.07 P7, P8 ...
rem Pietsch 19.06.07 gui
rem         21.06.07 bin ...
rem         28.06.07 echo Pn
rem         01.02.08 Xmx256M
rem         
rem
rem
SETLOCAL
echo Script: %0
echo.
echo P1 (Modus) =%1
echo P2 (VDN_Soft) =%2
echo P3 (JAVA_HOME) =%3
echo P4 (JAVA_bin) =%4
echo P5 (Data_Dir) =%5
echo P6 (Protokoll) =%6
echo P7 (BNA_Out) =%7
echo P8 (Proxy_User) =%8
echo P9 (Proxy_Pass) =***
echo.
rem
SET x_VDN=%2
SET JAVA_HOME=%3
SET x_BIN=%4
SET x_DIR=%5
SET x_PTK=%6
SET x_BNA=%7
SET x_USE=%8
SET x_PAS=%9
rem
SET PATH=%x_BIN%;%PATH%
rem
rem SET J_MEM=-Xmx64M
rem SET J_MEM=-Xmx192M
rem erforderlich fuer das Konvertieren von 33645 Stoerungen
SET J_MEM=-Xmx256M
rem
rem
rem SET J_LIB=-Djava.library.path=%2 rem funktioniert leider NICHT
rem
rem wegen moeglicher Leerzeichen im Pfad zu Robotron Software
rem setzen wir uns ins Verzeichnis ! (Hauptsaechlich jedoch damit die ganzen Lib's gefunden werden)
pushd %x_VDN%
rem
rem
rem ACHTUNG die beiden folgenden Zeilen werden von INTERASS ausgewertet
SET J_OPT=lib\vdnchecker.jar;lib\metouia.jar;lib\jdom.jar;lib\log4j-1.2.8.jar;lib\xmlParserAPIs.jar;lib\xercesImpl.jar
SET J_OPT1=lib\axis.jar;lib\axis-ant.jar;lib\commons-discovery-0.2.jar;lib\commons-logging-1.0.4.jar;lib\jaxrpc.jar;lib\saaj.jar;lib\wsdl4j-1.5.1.jar
rem
if "%1" == "pruefen" goto PRUEFEN
rem
SET J_OPT=%J_OPT%;%J_OPT1%
rem
if "%1" == "konvert" goto KONVERT
if "%1" == "senden"  goto SENDEN
if "%1" == "gui"     goto GUI
rem
echo Unbekannter P1=%1 !!
goto ENDE
rem
:PRUEFEN
echo Starte VDN-Pruefprogramm
rem %JAVA_HOME%\bin\java.exe %J_MEM% %J_LIB% -cp %J_OPT% de.robotron.sea.MainRun %x_DIR% %x_PTK%
java %J_MEM% -cp %J_OPT% de.robotron.sea.MainRun %x_DIR% %x_PTK%
goto ENDE
rem
:KONVERT
echo Starte VDN-Konvertierungsprogramm
java %J_MEM% -cp %J_OPT% de.robotron.sea.MainRun %x_DIR% %x_PTK% transform %x_BNA%
goto ENDE
rem
:SENDEN
echo Starte VDN-Konvertierungsprogramm mit Sendeoption
java %J_MEM% -cp %J_OPT% de.robotron.sea.MainRun %x_DIR% %x_PTK% send %x_BNA% %x_USE% %x_PAS%
goto ENDE
rem
:GUI
rem P4 = INTERASS Arbeitsverzeichnis
echo Starte GUI VDN-Konvertierungsprogramm
java %J_MEM% -Djava.io.tmpdir=%x_DIR% -Duser.home=%x_DIR% -cp %J_OPT% de.robotron.sea.MainRun
rem
:ENDE
popd
ENDLOCAL
